Newton’s Method on TI-83/84 or TI-89

Summary: Newton’s Method is a fast way to home in on real solutions of an equation. Your TI-83/84 or TI-89 can do Newton’s Method for you, and this page shows two ways.

Newton’s Method is iterative, meaning that it uses a process or recipe to move from each guess x_n to the next guess x_n+1. The recipe for Newton’s Method is shown at right. This recipe takes a tangent line to the curve at x = x_n, finds the x value where that line crosses the x axis, and uses that x value as the next guess x_n+1. Any calculus textbook will have an illustration of the method.

What we are “guessing” is a zero of a real-valued function. If the guesses get progressively closer to the desired point, we say that the method converges. It turns out that if Newton’s Method converges at all to a particular zero, it converges rapidly, meaning that it takes relatively few steps. (See your textbook for conditions in which Newton’s Method converges.)

To start either method, put the equation you want to solve into f(x) = 0 form. Technically Newton’s Method finds zeroes of a function, not roots of an equation. Therefore you would rewrite something like x sin x = 2 as x sin x − 2 = 0. (Remember from algebra that a zero of function f is the same as a solution or root of the equation f(x) = 0 or an x intercept of the graph of f.)

Method 1: You Differentiate

To practice Newton’s Method, let’s find the square root of 2, since it will be easy to check the answer. √2 is a solution of x = √2 or x² = 2. To start, rewrite it in the form f(x) = x² − 2 = 0.

Next, differentiate the function: f′(x) = 2x.

Enter the function as Y1 and the derivative as Y2.	TI-83/84: Press [Y=].   In Y1, press [x,T,θ,n] [x²] [−] [2].   In Y2, press [2] [x,T,θ,n]. Then cursor back to the = sign and press [ENTER]. This tells the TI-83/84 not to graph the derivative Y2.	TI-89: Press [◆] [Y=].   In Y1, press [X] [^] [2] [−] [2] [ENTER]   In Y2, press [2] [X] [ENTER] then [▲] [F4] to tell the TI-89 not to graph the derivative Y2.
(optional) Graph the function to plan your initial guess.	TI-83/84: Press [ZOOM] [6] for ZStandard (standard zoom).	TI-89: Press [F2] [6] for ZoomStd.
Return to the home screen.	TI-83/84: Press [2nd MODE makes QUIT].	TI-89: Press [2nd ESC makes QUIT].

Next you’ll set x to your first guess, then program the recipe fr getting the next guess. Let’s guess 1 to start.

Store the initial guess, 1, in X.	TI-83/84: Press [1] [STO→] [x,T,θ,n].	TI-89: Press [1] [.] [STO→] [X]. The decimal point is important: it tells the TI-89 that you want decimal approximations rather than exact numbers.
Since y1 is the left-hand side of the equation to be solved and y2 is the derivative, you want to subtract y1/y2 from x and store the result in x as the next guess.   After the first iteration, you see the result is 1.5.	TI-83/84: [x,T,θ,n] [−] [VARS] [►] [1] [1] pastes Y1 to screen. [÷] [VARS] [►] [1] [2] pastes /Y2 to screen. [STO→] [x,T,θ,n] [ENTER] computes the next guess and stores it in X.	TI-89:  You must supply the argument (X) to the two functions. [X] [−] [Y] [1] [(] [X] [)] [÷] [Y] [2] [(] [X] [)] [STO→] [X]
Now iterate until the guesses converge.	Both: Each additional [ENTER] key computes a further guess.   After just four more iterations, the process has converged. (If you want, you can press [^] [2] to verify that this is indeed the square root of 2.)
	TI-83/84:	TI-89:

Method 2: Calculator Program

The TI-83/84 and TI-89 are programmed somewhat differently. You can download programs for both calculator families in the file NEWTON.ZIP (31 KB, revised 28 Dec 2016), or you can key in the program following the directions below.

The TI-83/84 program to run Newton’s Method should work for any function, even one you don’t know how to differentiate, because it computes the derivative numerically. The TI-89 program will work for any differentiable function, because the TI-89 finds the algebaic derivative for you.

Disp "INITIAL GUESS"
Input X
1→N
Lbl 1
X-Y1/nDeriv(Y1,X,X)→R
If abs(X-R)<abs(X/1E10)
Goto 2
R→X
Disp {X,N}
N+1→N
Goto 1
Lbl 2
Disp "ROOT=",R
Disp "ITER=",N

(t)
Prgm
getMode("Exact/Approx")→str1
setMode("Exact/Approx","Approximate")
ClrIO
Disp "Initial guess=",t
1→z
Loop
  t-y1(t)/(d(y1(x),x))|x=t→y
  If abs(t-y)<abs(t/1E10)
    Exit
  z+1→z
  y→t
EndLoop
Disp "Root=",y
Disp "Iterations=",z
setMode("Exact/Approx",str1)
DelVar str1
EndPrgm

Let’s test the program by finding a solution of x = cos(x). That means finding the positive zero of f(x) = x − cos(x). We’ll use an initial guess of 0.

Make sure the calculator is in radian mode.

Put the function into Y1.	TI-83/84: [Y=]   In Y1, press [x,T,θ,n] [−] [COS] [x,T,θ,n] [)]	TI-89: [◆] [Y=]   In Y1, press [X] [−] [2nd Z makes COS] [X] [)]
Return to the home screen.	TI-83/84: Press [2nd MODE makes QUIT].	TI-89: Press [2nd ESC makes QUIT].
Run the program.	TI-83/84: Press [PRGM], then the number next to the NEWTON program. (This number will vary depending on any other programs in your calculator.) Press [ENTER] to start the program.   You’re prompted for an initial guess. Enter 0.	TI-89:  Press [2nd − makes VAR-LINK], scroll to newton, and press [ENTER]. This pastes newton( to your home screen.   Enter the initial guess, 0, and then [)] [ENTER].
The program finds the answer, about 0.7391, in six iterations.	TI-83/84:	TI-89: