How to Add Vectors Graphically on TI-83/84

Summary: You can add vectors (or complex numbers) graphically on your TI-83 or TI-84 with a simple program, presented here. The hard part, also presented here, is automatically adjusting all the window parameters to show the vectors in proper perspective.

VECADD will prompt for two vectors, then display the result vector numerically and graphically. You can enter the vectors in component form or length-magnitude form. The program gives the result vector’s components, length, and magnitude.

See also: If you don’t want the graphics, you can treat the vectors as complex numbers in a+bi form and just add them. Complex Numbers on TI-83/84 explains.

Getting the Program

If you have the TI Connect or TI Graph Link software, you can download the program from this ZIP file (25 KB, revised 28 Dec 2016), unzip it to any convenient directory, and download it to your TI-83 or TI-84.

Otherwise, you can enter the program manually, as shown below.

Running the Program

Press the [PRGM] key, and select VECADD; see prgmVECADD appear on your home screen. Press [ENTER] to run the program.

Example: vectors [3,−8] and [5,6].

1. When prompted, enter the components of the two input vectors.
2. VECADD shows you the components, length, and angle of the result vector. (The angle will be between −180° and 180°, or between −π and π, depending on whether you selected degrees or radians on the Mode screen.)
3. Then when you press [ENTER], VECADD shows you the two input vectors and the result. The program automatically adjusts the screen margins, aspect ratio, and grid spacing.

You can redisplay the numbers by pressing [2nd MODE makes QUIT], then return to the graph by pressing [GRAPH].

Example: vectors 15.00∠38° and 27.00∠130°. The VECADD program can deal with vectors in length-angle form — you just enter the x as (length) cos(angle) and the y as (length) sin(angle). The calculator computes and displays the input vectors in component form.

As before, the result vector is displayed both as components and in length-angle form, 30.43∠100.5° in this case. On the graphical display, the grid spacing is automatically adjusted to dots every 10 units.

Entering the Program

It’s easiest to download the program, if you have the TI Connect or TI Graph Link software. Failing that, you can keyboard it following these instructions.

If you’re not familiar with TI-83/84 programming instructions, you might want to practice first with a shorter program, like the quadratic equation solver.

The program VECADD divides into four phases:

1. Get components of the two input vectors.
2. Compute and display components of the result.
3. Compute window parameters for graphical display.
4. Add the vectors graphically.

I’ll show you each phase, discuss the meaning of the instructions, and tell you which keystrokes to use where they’re not obvious.

Phase 1 — Get components of input vectors.

Input "X1:",A
Input "Y1:",B
Input "X2:",C
Input "Y2:",D

ClrHome
Disp {A,B}
Disp {C,D}

At this point — actually, at any point — you can press [2nd MODE makes QUIT] to leave the program editor. Later, when you’re ready to continue entering program commands, press [PRGM] [►] and select VECADD.

Phase 2 — Display result vector numerically.

Two short lines compute the vector sum. (You store components of the result vector in variables E and F, not X and Y, because the TI-83/84 changes X and Y while drawing lines.)

As with most programs, displaying the results takes more work than computing them! Here you’ll display the result vector in both component form and length-angle form, then prompt the user to continue.

A+C→E
B+D→F

Output(3,1,"X:")
Output(3,3,E)
Output(4,1,"Y:")
Output(4,3,F)

Output(5,1,"R:")
Output(5,3,R→Pr(E,F))

Output(6,1,"θ:")
Output(6,3,R→Pθ(E,F))

Disp "","","","","    PRESS ENTER"

Pause

At this point you might want to run the program to make sure that the computations and text displays are correct.

Phase 3 — Compute window parameters for graphical display.

The next phase of the program adjusts the parameters on the Window screen to fit all three vectors on the screen. This is the most complex section of the program, but it’s much better to have the program set up the screen than force the user to do it each time.

3a — Set Xmin, Xmax, Ymin, and Ymax

To begin this phase, set the four screen margins.

Input vector 1 goes from (0,0) to (A,B), vector 2 goes from (0,0) to (C,D), and the result goes from (0,0) to (E,F). The program sets Xmin to the smallest of all those x endpoints and Xmax to the largest, then sets Ymin and Ymax to the smallest and largest y endpoints.

min( ) selects the smallest in a list of numbers, and max( ) selects the largest. Note the braces inside the parentheses, needed to make the TI-83/84 treat the numbers as a list.

min({0,A,C,E})→Xmin

max({0,A,C,E})→Xmax

min({0,B,D,F})→Ymin
max({0,B,D,F})→Ymax

3b — Set grid spacing

You want some dots on the screen, preferably enough to guide the eye without cluttering up the display. The following computation looks at whether the x or y range is greater and sets between 2 and 20 dots in that direction, sets the other direction to have the same dot spacing, and turns the grid on.

10^int(log(max(Xmax-Xmin,
Ymax-Ymin)/2))→Xscl

Xscl→Yscl

GridOn

3c — Adjust the aspect ratio

Because the screen isn’t square, the program needs to adjust either the horizontal or the vertical value of a pixel. This is essentially what happens when you do ZSquare (zoom square).

max({ΔX,ΔY})→ΔX
max({ΔX,ΔY})→ΔY

Phase 4 — Add the vectors graphically.

Now that the screen margins and grid have been set up, it’s time to draw the vectors.

ClrDraw
FnOff
PlotsOff

Line(0,0,A,B)
Line(0,0,C,D)
Line(A,B,E,F)
Line(C,D,E,F)
Line(0,0,E,F)

Now reap your reward by running the program.